\ LCD ATTRIBUTE PAL
\ PIVOT-2
\ 2/25/85
\ H. FULLMER
\ 4/15/85 UPDATED FOR REV. C CPU  H.F.
\ 6/10/85 AT3 INVERTED IN BLANK.  H.F.
\ 6/12/85 REVISED ATTRIBUTE HANDLING. H.F.
\
\ REV 2.1
\ 7/29/85 ADDED CURSOR BLINK (MUST BE USED WITH KEYBOARD ROM 6.05 OR LATER)
\
\ 		P A L    T Y P E


PALS   16L8


\   	P I N    A S S I G N M E N T S

1.	AT6

2.	AT5

3.	BLINK

4.	BLENB

5.	SSIX

6.	CURD

7.	AT0

8.	AT1

9.	AT2

10.	GND

11.	AT4

12.	/REV

13.	EQUAL

14.	/GREATER

15.	AT3

16.	AT7

17.	/E_REV

18.	/ATLATCH

19.	/BLANK

20.	VCC


\	E Q U A T I O N S




/ EQUAL		\ TRUE IF AT0-2 = AT4-6
		=    HI

		+    AT2  *  / AT6
		+    / AT2  *  AT6

		+    AT1  *  / AT5
		+    / AT1  *  AT5

		+    AT0  *  / AT4
		+    / AT0  *  AT4


/ /E_REV	\ TRUE IF REVERSE PROCESSING
		=    HI

		+    AT3  *  BLENB  *  / SSIX
		+    AT3  *  / AT7  *  / BLENB  *  / SSIX
		+    / AT3  *  AT7  *  / BLENB  *  SSIX

		+    / AT3  *  BLENB  *  AT2
		+    / AT3  *  / AT7  *  / BLENB  *  AT2
		+    AT3  *  AT7  *  / BLENB  *  AT2


/ /GREATER	\ TRUE IF AT0-2 > AT4-6
		=    HI

		+    AT2  *  / AT6

		+      AT2  *   AT6  *  AT1  *  / AT5
		+    / AT2  * / AT6  *  AT1  *  / AT5

		+      AT2  *   AT6  *   AT1 *   AT5  *  AT0  *  / AT4
		+    / AT2  * / AT6  *   AT1 *   AT5  *  AT0  *  / AT4
		+      AT2  *   AT6  * / AT1 * / AT5  *  AT0  *  / AT4
		+    / AT2  * / AT6  * / AT1 * / AT5  *  AT0  *  / AT4



/ /BLANK	\ BLANK CHARACTER
		=    HI

		+    EQUAL  *  BLENB  *  / AT3
		+    EQUAL  *  / BLENB  *  AT3  *  AT7
		+    EQUAL  *  / BLENB  *  / AT3  *  / AT7

		+    BLINK  *  AT7  *  BLENB

		+    / SSIX  *  / AT3  *  / /ATLATCH  *  / /GREATER


/ /REV		\ REVERSE CHARACTER
		=    HI

		+    /GREATER  *  / EQUAL  *  / CURD
		+    EQUAL  *  / /E_REV  *  / CURD

		+    /GREATER  *  / EQUAL  *  CURD  *  BLINK
		+    EQUAL  *  / /E_REV  *  CURD  *  BLINK

		+    / /GREATER  *  CURD  *  / BLINK
		+    EQUAL  *  /E_REV  *  CURD  *   / BLINK


END