1000 REM *** BEURS ***
1010 REM *** Versie januari 1984 door J.N. Verwoerd ***
1020 DIM C(6),S(3,6),M(3),A(3)
1030 ON ERROR GOTO 2450
1040 PRINT CHR$(26)+CHR$(7)
1050 PRINT:PRINT:PRINT:PRINT
1060 T=50:REM *** AANTAL DOLLARS WAARMEE WORDT GESTART
1070 T1=100:REM *** AANTAL DOLLARS WAARMEE HET SPEL EINDIGT
1080 PRINT TAB(20)"********** BEURS SPEL **********":PRINT:PRINT:PRINT:PRINT
1090 PRINT:PRINT:PRINT
1100 INPUT "TYPE EEN 3 CIJFERIG NUMMER";R1
1110 R1=RND(-R1/1000)
1120 P1=INT(6*RND(R1))+1:Q1=INT(6*RND(R1))+1
1130 FOR I=1 TO 3:M(I)=T:NEXT I:PRINT
1140 PRINT "HOEVEEL SPELERS (1-3)";:INPUT Q:PRINT
1150 IF Q<1 THEN 1140 ELSE IF Q>3 THEN 1140
1160 FOR I=1 TO 6:C(I)=INT(6*RND(I))+1:NEXT I
1170 PRINT "WENST U INSTRUCTIES? (Y=JA)";:INPUT A$
1180 IF A$="Y" THEN GOSUB 2120
1190 GOSUB 1620
1200 FOR B=1 TO Q
1210 PRINT "***  DE BEURT IS AAN SPELER";B;
1220 PRINT "***   "TAB(43)"********************************"
1230 PRINT TAB(43)"* OPTIE 1     = KOPEN/VERKOPEN *"
1240 C=INT(6*RND(P1))+1:S=INT(6*RND(Q1))+1
1250 PRINT TAB(43)"* OPTIE 2     = STIJGEN/DALEN  *"
1260 PRINT "U HEEFT EEN"C"EN EEN"S"GEWORPEN";
1270 PRINT TAB(43)"* AANDELEN: - = VERKOPEN/DALEN *"
1280 PRINT "TOETS: OPTIE, FIRMA, AANDELEN   (O,F,A)";
1290 PRINT TAB(43)"********************************"
1300 INPUT; O1,C1,S1
1310 IF C1=C THEN 1320 ELSE IF C1=S THEN 1330 ELSE  2450
1320 IF S=ABS(S1) THEN 1340 ELSE  2450
1330 IF C=ABS(S1) THEN 1340 ELSE  2450
1340 IF O1=2 THEN 1460 ELSE IF O1<>1 THEN 2450 ELSE IF S1<0 THEN 1400
1350 C2=(S1*C(C1))+(.05*(S1*C(C1)))
1360 IF M(B)>C2 THEN 1380
1370 PRINT " PERSOON"B"HEEFT NIET GENOEG GELD.";:GOTO 1300
1380 S(B,C1)=S(B,C1)+S1:M(B)=M(B)-C2
1390 GOTO 1520
1400 IF S(B,C1)+S1>=0 THEN 1430
1410 PRINT " ZOVEEL AANDELEN HEEFT U NOU OOK WEER NIET -- PROBEER HET NOG EENS"
1420 GOTO 1300
1430 C2=(S1*C(C1))-(.05*(S1*C(C1)))
1440 M(B)=M(B)+ABS(C2)
1450 S(B,C1)=S(B,C1)+S1
1460  IF C(C1)+S1>0 THEN 1490
1470 PRINT "DAT KUNT U NIET DOEN! AANDELEN DUIKEN ONDER NULWAARDE!";
1480 GOTO 1300
1490 C(C1)=C(C1)+S1
1500 PRINT " DE AANDELEN VOOR FIRMA"C1"KOSTEN NU $"C(C1)
1510 FOR F=1 TO 750:NEXT F
1520 IF M(B)>=T1 THEN 1570
1530 IF B=Q THEN 1540 ELSE GOSUB 1630
1540 NEXT B
1550 GOSUB 1630
1560 GOTO 1200
1570 PRINT:GOSUB 1630:PRINT:PRINT
1580 PRINT "******************** HET SPEL IS UIT ********************"
1590 PRINT:PRINT
1600 PRINT "*** DE FELICITATIES VOOR DE WINNAAR ***"
1610 GOTO 2470
1620 PRINT CHR$(26):GOTO 1640
1630 PRINT CHR$(30):M=0
1640 PRINT TAB(20)"***** BEURS OVERZICHT *****"
1650 PRINT "-------- AANDELEN --------";
1660 PRINT TAB(29)"**SPELER 1*   **SPELER 2*   **SPELER 3*"
1670 PRINT "NR    FIRMA"TAB(19)"$/AAND";
1680 PRINT TAB(29)"ST    WAARDE  ST    WAARDE  ST    WAARDE"
1690 A9=0:FOR I=1 TO 6:PRINT I;TAB(4);
1700 IF I=1 THEN PRINT "DIAMONDS INC";:GOTO 1760
1710 IF I=2 THEN PRINT "MINI-COMP";:GOTO 1760
1720 IF I=3 THEN PRINT "MUTUAL MOTORS";:GOTO 1760
1730 IF I=4 THEN PRINT "MEANCHILD ELEC";:GOTO 1760
1740 IF I=5 THEN PRINT "GRANDPA BELL";:GOTO 1760
1750 PRINT "BROKE FINANCE";:GOTO 1760
1760 A9=A9+C(I):PRINT TAB(21);C(I);
1770 FOR K=1 TO Q
1780 PRINT TAB(((K-1)*14)+29);S(K,I);
1790 PRINT TAB(((K-1)*14)+35);S(K,I)*C(I);
1800 NEXT K:PRINT:NEXT I
1810 PRINT TAB(28)"---------------------------------------"
1820 PRINT TAB(4)"TOTALEN";
1830 FOR I=1 TO 3:A(I)=0:NEXT I
1840 FOR I=1 TO Q:B9=0:C9=0
1850 FOR X=1 TO 6
1860 B9=B9+S(I,X)
1870 C9=C9+(S(I,X)*C(X))
1880 A(I)=A(I)+(S(I,X)*C(X))
1890 NEXT X
1900 PRINT TAB(((I-1)*14)+29);B9;
1910 PRINT TAB(((I-1)*14)+35);C9;
1920 NEXT I:PRINT
1930 PRINT TAB(4);"CONTANT";
1940 FOR I=1 TO Q:M(I)=INT(M(I)*100)/100
1950 PRINT TAB(((I-1)*14)+31);M(I);:A(I)=A(I)+M(I)
1960 NEXT I:PRINT
1970 PRINT TAB(4);"TOTAAL BEZIT ";
1980 FOR I=1 TO Q:PRINT TAB(((I-1)*14)+31);A(I);
1990 NEXT I:PRINT:PRINT CHR$(23)
2000 PRINT "GEMIDDELDE PRIJS PER AANDEEL $";
2010 A9=A9/6:A9=INT(A9*100)/100
2020 PRINT A9;
2030 IF A9-A8<>0 THEN 2050
2040 PRINT "GEEN KOERSVERANDERING!":GOTO 2090
2050 IF A9-A8<0 THEN 2080
2060 PRINT ", EEN STIJGING MET";A9-A8;"DOLLARS PER AANDEEL!"
2070 GOTO 2090
2080 PRINT ", EEN DALING MET";A8-A9;"DOLLARS PER AANDEEL!"
2090 A8=A9
2100  FOR I=1 TO 2000:NEXT I
2110 RETURN
2120 PRINT CHR$(26):PRINT:PRINT:PRINT
2130 PRINT "----------------------------------------------------------------"
2140 PRINT "DIT IS EEN BEURS SPEL. DE BEDOELING VAN DIT SPEL IS"
2150 PRINT "MEER GELD TE MAKEN MET DE EFFECTENHANDEL DAN DE ANDEREN."
2160 PRINT "U DOET DAT DOOR KOPEN EN VERKOPEN VAN AANDELEN."
2170 PRINT "----------------------------------------------------------------"
2180 PRINT "DE MANIER WAAROP U AANDELEN KOOPT EN VERKOOPT GAAT ALS VOLGT."
2190 PRINT "U GOOIT TWEE DOBBELSTENEN; A EN B. U KUNT OF 'A' AANDELEN IN"
2200 PRINT "FIRMA 'B' KOPEN OF 'B' AANDELEN IN FIRMA 'A'."
2210 PRINT "HETZELFDE GELDT VOOR HET VERKOPEN, MAAR U KUNT NIET MEER"
2220 PRINT "AANDELEN VERKOPEN DAN U IN UW BEZIT HEEFT. OVER ALLE"
2230 PRINT "TRANSACTIES MOET TEVENS 5% KOSTEN WORDEN BETAALD VOOR"
2240 PRINT "BEMIDDELING DOOR EEN MAKELAAR."
2250 PRINT:PRINT:PRINT:PRINT:PRINT
2260 PRINT "TOETS -RETURN- OM DOOR TE GAAN...";:INPUT Z
2270 PRINT CHR$(26):PRINT:PRINT:PRINT:PRINT
2280 PRINT "OM TE BEWERKSTELLIGEN DAT EEN AANDEEL STIJGT OF DAALT, GEBRUIKT"
2290 PRINT "U UW BEURT NIET OM TE KOPEN OF TE VERKOPEN, MAAR OM DE PRIJS VAN"
2300 PRINT "EEN BEPAALD AANDEEL TE LATEN STIJGEN OF DALEN. U DOET DIT DOOR"
2310 PRINT "WAARDEVERMEERDERING VAN 'A' AANDELEN MET 'B' DOLLARS OF VERMIN-"
2320 PRINT "DERING VAN 'A' AANDELEN MET 'B' DOLLARS. HET WERKT OOK ANDERSOM;"
2330 PRINT "U KUNT OOK 'B' AANDELEN MET 'A' DOLLARS LATEN STIJGEN OF DALEN."
2340 PRINT "----------------------------------------------------------------"
2350 PRINT "*** OPTIE 1 WORDT GEBRUIKT BIJ HET KOPEN OF VERKOPEN VAN AANDELEN"
2360 PRINT "*** OPTIE 2 WORDT GEBRUIKT BIJ HET STIJGEN OF DALEN VAN DE PRIJS"
2370 PRINT "*** TYPE EEN NEGATIEF NUMMER VOOR DE AANDELEN OM TE VERKOPEN OF"
2380 PRINT "    OM DE PRIJS VAN DE AANDELEN TE LATEN DALEN."
2390 PRINT "*** LET OP! BIJ VERKOOP DAALT DE PRIJS PER AANDEEL OOK! !"
2400 PRINT "----------------------------------------------------------------"
2410 PRINT "EEN IEDER START MET"T"DOLLARS EN HET SPEL IS UIT ZODRA EEN"
2420 PRINT "SPELER"T1"DOLLARS CONTANT HEEFT VERGAARD."
2430 PRINT "VEEL GELUK ! ! ! !":PRINT:PRINT
2440 PRINT "TOETS -RETURN- OM TE BEGINNEN...";:INPUT Z:RETURN
2450 PRINT CHR$(7)+"   INVOERFOUT --> ";:M=M+1:IF M=3 THEN 2460 ELSE 1300
2460 PRINT:PRINT:PRINT"LEES DE INSTRUCTIES ! ! !"
2470 PRINT:PRINT"EINDE PROGRAMMA":END
";:M=M+1:IF M=3 THEN 2460 ELSE 1300
2460 PRINT:PRINT:PRINT"LEES DE INSTRUCTIES ! ! !"
2470 PRINT:PRINT"EINDE PROGRAMMA":E